@edit cambot_action.muf
1 99999 d
1 i
( cambot_action.muf 04/10/01 by BoingDragon
  This is the primary program of the cambot system. It can be used alone in a room
  or as part of a holodeck and Furry Science Theater 3000 setup.
 
  In a room or parent room link a 'cambot' action to this program, then type 'cambot'
  to display usage and set the command aliases.
 
  To use with FST3K rooms, set the property 'fst3k_parent:<db number, no #>' in the
  room the action lives in.
 
  By default, logs will be saved on the rooms they are recorded in, unless a 'library'
  property is set in the room or parent which has the db number <without the # sign>
  of an object to save them to.
 
  Editing and other permissions flow as follows:
    library owner -> log owner -> line owner
 
  Line owners can edit, delete and change lines they created
  Log owners have full control over all lines of the log and can delete logs
  Library owners have full control over all logs by all owners

  Program properties:
    "recorder" on the program object must be set to the number of room_recorder.muf,
    without the # sign. 
 
  Library object properties:
    "_auth_users", set to their db numbers {no # signs} seperated by spaces will give
    those users library-owner level permissions over that library. 
)
 
$def ACTION_NAME "cambot;closeup;logs;setlog;clearlog;setline;deleteline;changeline;swapline;lastline;startlog;stoplog;printlog;viewlog;viewlast;addnote;hr;icdate"
$def CLOSEUP_OPEN "<div class=\"vista\">"
$def CLOSEUP_CLOSE "</div>"
$def LOGLINE_OPEN "<p class=\"logline\">"
$def LOGLINE_CLOSE "</p>"
$include $lib/case
$include $lib/sort
 
lvar actname
lvar logname
lvar linenumber
lvar start-type
lvar startline
lvar stopline
lvar inarg
lvar loglib
lvar shownumbers
lvar doublespace
lvar fst3k
lvar channel
lvar count
lvar index
lvar logowner
lvar lineowner
lvar oldstring
lvar newstring
lvar targetname
lvar targetdb
lvar image
lvar switch
lvar recorder
lvar fst3k_parent
lvar age
lvar spi
lvar pdb
lvar parg
lvar authlist
 
(Begin Greywolf function block) 
: tell ( s -- : return message to user )
  me @ swap notify
;
()
: even? ( i -- 0|1 : return 1 if even, 0 if odd )
  2 % not
;
()
: extract-char ( s1 i -- s2 : return the ith character of s1 )
  dup 1 = if  ( handle i = 1 as special case to avoid error below )
   strcut pop exit
  then
  over over strcut pop  ( remove all characters after i )
  rot pop swap ( remove input string )
  (stack: s2 i )
  1 - strcut swap pop ( remove all characters before i )
;  
()
: split-remove ( s1 i -- s2 s3 : return strings on both sides of i )
  dup 1 = if ( handle i = 1 as special case to avoid error )
    strcut swap pop "" swap exit
  then
  over over strcut 
  (stack: s1 i s s3 )
  swap pop ( split off characters after i )
  (stack: s1 i s3 )
  rot rot 1 - strcut pop ( split off characters before i )
  (stack: s3 s2 )
  swap
;
()
: numeric? ( s1 -- 0|1 : returns 1 if numeric, 0 if not )
  dup "0" strcmp not if
    pop 1 exit
  then
  atoi 0 > if
    1
  else
    0
  then
;
()
: last-char ( s1 -- s2 : returns last character of s1 )
  dup strlen dup 2 < if
    pop exit
  then
  1 - strcut swap pop
;
()
: html-convert ( s1 s2 s3 -- s4 : convert key codes to html)
  (s1 = input string ; s4 = output string )
  (s2 = key code -- example '*' )
  (s3 = html code -- example 'b' )
  ()
  (note:  if this function is unable to get a 'clean' convert, it will 
   return the line with no changes.  The reasoning is that it is better 
   to leave things be than to convert wrongly.)
()
  rot
  (stack: * b s1 )
  dup 4 pick instr not if  ( if no "*" at all, leave line untouched )
    swap pop swap pop exit (clean stack and quit)
  then
  (stack:  * b s1 )
  0 "" 3 pick  ( stack: * b s1 counter rebuild workstring )
  begin
    dup 7 pick instr dup not if ( no more * to process )
      pop strcat
      swap even? if 
        swap pop   ( remove input string )
        break
      else
        (if odd occurrences of *, then something is wrong)
        (abort and return original string)
        pop
        break
      then
    then
    (stack: * b s1 counter rebuild workstring position )
    split-remove
    (stack: * b s1 counter rebuild part1 workstring )
    rot rot strcat swap
    (stack: * b s1 counter rebuild workstring )
()
    over last-char
    (stack: * b s1 counter rebuild workstring last-char )
    dup "<" strcmp not ( is < last character? )
    (stack: * b s1 counter rebuild workstring last-char i )
    swap 8 pick strcmp not or if  ( is * last character? )
      (stack: * b s1 counter rebuild workstring )
      swap 6 pick strcat swap ( if so, don't convert this time )
      continue
    then
()
    (stack: * b s1 counter rebuild workstring )
    dup 1 strcut pop 7 pick strcmp not if ( is * next character? )
      swap 6 pick strcat swap ( if so, don't convert this time )
      continue
    then
()
    (stack: * b s1 counter rebuild workstring )
    dup 1 strcut pop numeric? if ( is next character numeric? )
       over last-char numeric? if ( is previous character numeric? )
          swap 6 pick strcat swap ( if so, don't convert this time )
          continue
       then
    then
()
    3 pick even? if
      swap "<" 6 pick ">" strcat strcat strcat swap (stick tag after 'rebuild' portion )
    else
      swap "</" 6 pick ">" strcat strcat strcat swap (end bold html indicator )
    then
    rot 1 + rot rot ( increment counter, put back in stack )
  repeat
;
()
: bold-convert ( s1 -- s2 : convert *bold* to <b>bold</b> )
  "*" "b" html-convert
;
()
: italics-convert ( s1 -- s2 : convert /italics/ to <i>italics</i> )
  "/" "i" html-convert
;
()
: underline-convert ( s1 -- s2 : convert _underline_ to <u>underline</u> )
  "_" "u" html-convert
;
(End Greywolf function block)
 
: holodeck
  ME @ location
;
 
: get-logname
  holodeck "logname" getpropstr logname ! ( get the name of the current log )
; 
 
: set-logname
  holodeck swap "logname" swap setprop
;
 
: log-prop
  "logs/" logname @ strcat
;
 
: log-propdir
  log-prop "/" strcat
;
 
: log-status
  loglib @ log-prop "/status" strcat getpropstr
;
 
: set-status
  inarg !
  loglib @ log-propdir "status" strcat inarg @ setprop
;
 
: get-line
  loglib @ log-prop getpropval
;
 
: addline
  inarg !
  get-line linenumber !
  linenumber @ 1 + linenumber !
  loglib @ log-propdir linenumber @ intostr strcat inarg @ setprop
  loglib @ log-prop linenumber @ setprop
;
 
: addnote
  log-status "recording" strcmp if
    ">> The cambot isn't recording now! <<" tell
    exit
  then
  ME @ name " notes: " strcat inarg @ strcat inarg !
  holodeck #-1 ">> " inarg @ strcat " (OOC)" strcat notify_except
  "<!-- " inarg @ strcat " -->" strcat addline
;

: icdate
  log-status "recording" strcmp if
    ">> The cambot isn't recording now! <<" tell
    exit
  then
  "<!-- IC Date: " inarg @ strcat " -->" strcat addline
  ME @ name " notes the date: " strcat inarg @ strcat inarg !
  holodeck #-1 ">> " inarg @ strcat " (OOC)" strcat notify_except
;
 
: get-channel
  "0" channel !
  holodeck "fst3k_parent" envprop swap #-1 dbcmp not if 
    atoi dbref fst3k_parent !
    fst3k_parent @ "room/" nextprop channel !
    begin
    fst3k_parent @ channel @ getpropstr holodeck intostr strcmp while
      fst3k_parent @ channel @ nextprop channel !
    repeat
    channel @ 5 strcut swap pop channel !
  else
    pop 
  then
;
 
: auth-user?
  loglib @ log-propdir "owner" strcat getpropval dbref logowner !
  logowner @ ME @ dbcmp loglib @ owner ME @ dbcmp or ME @ "W" flag? or if
    1
  else
    0 index !
    loglib @ "_auth_users" getpropstr authlist !
    authlist @ strlen if
      authlist @ " " explode count !
      begin
      count @ 0 > while
        atoi dbref ME @ dbcmp if 1 index ! then
        count @ 1 - count !
      repeat
    then
    index @ 
  then
;
 
: fst3k-notify
  inarg !
  (FST3K notify)
  fst3k_parent @ dbref? if
    fst3k_parent @ contents fst3k !
    begin
      fst3k @ room? if
        fst3k @ #-1 inarg @ notify_except
      then
      fst3k @ next fst3k !
    fst3k @ #-1 dbcmp until
  then
;
 
: addbreak
  log-status "recording" strcmp if
    ">> The cambot isn't recording now! <<" tell
    exit
  then
  holodeck #-1 "<hr align=center width=50%>" notify_except
;
 
: startlog
  logname @ strlen 0 = if ( if no current log name set, create one based on the date )
    "%b-%d-%Y" systime timefmt logname !
    holodeck "logname" logname @ setprop
  then
  log-status "recording" strcmp not if
    ">> That log is already being recorded to! <<" tell
    exit
  then
  ( get the last line index if it exists )
  get-line linenumber !
  ( if no previous linenumber set, create new one, else increment )
  linenumber @ 1 < if
    "started" start-type !
    loglib @ log-propdir "owner" strcat ME @ int setprop ( first person to start log is log owner )
  else
    "restarted" start-type !
  then
  "recording" set-status
  loglib @ log-propdir "time" strcat systime setprop
  ( generate and save startlog line )
  "<!-- (OOC) Log \"" logname @ strcat "\" " strcat start-type @ strcat " by " strcat ME @ name strcat " at " strcat "%r %a %b %d, %Y" systime timefmt strcat " (OOC) -->" strcat
  addline
  ( set environment properties )
  holodeck "recording" "yes" setprop
  holodeck "_arrive/cambot" "&>> Cambot is recording in this room <<" setprop
  holodeck "_connect/cambot" "&>> Cambot is recording in this room <<" setprop
  holodeck "_listen/cambot" recorder @ setprop
  ( messages )
  ">> You start cambot recording <<" tell
  holodeck ME @ ">> (OOC) " ME @ name strcat " starts cambot recording <<" strcat notify_except
  holodeck "private" getprop not if
    get-channel
    ">> " ME @ name strcat " begins recording '" strcat logname @ strcat "' on channel " strcat channel @ strcat " <<" strcat
    fst3k-notify
  then
;
 
: stoplog
  log-status "recording" strcmp if
    ">> The log is already stopped <<" tell
    exit
  then
  holodeck "recording" "no" setprop
  holodeck "_arrive/cambot" remove_prop
  holodeck "_connect/cambot" remove_prop
  holodeck "_listen/cambot" remove_prop
  ( generate and save stoplog line )
  "<!-- (OOC) Log \"" logname @ strcat "\" stopped by " strcat ME @ name strcat " at " strcat "%r %a %b %d, %Y" systime timefmt strcat " (OOC) -->" strcat 
  addline
  "archive" set-status
  ( messages )
  ">> You stop cambot recording <<" tell
  holodeck ME @ ">> " ME @ name strcat " stops cambot recording <<" strcat notify_except
  holodeck "private" getprop not if
    get-channel
    ">> " ME @ name strcat " stops recording '" strcat logname @ strcat "' on channel " strcat channel @ strcat " <<" strcat
    fst3k-notify
  then
;
 
: logs
  0 count !
  ">> Available logs: + = campaign, - = archived, * = recording" tell
  inarg @ strlen 0 > if
    loglib @ "logs/" inarg @ strcat "/" strcat nextprop logname !
  else
    loglib @ "logs/" nextprop logname !
  then
  begin
  logname @ strlen 0 > while
    loglib @ logname @ getpropval 0 > if
      systime loglib @ logname @ "/time" strcat getpropval - age !
      1000000 age @ age @ 86400 % - 86400 / + intostr "|" strcat
      loglib @ logname @ "/status" strcat getpropstr "recording" strcmp if
        "-  \"" strcat
      else
        "*  \"" strcat
      then
      logname @ 5 strcut swap pop strcat
      "\"" strcat
      dup strlen 48 > if
        "  (" strcat
      else
        "                                                                                 " strcat
        48 strcut pop "(" strcat
      then
      age @ age @ 86400 % - 86400 / intostr strcat " days/" strcat
      loglib @ logname @ getpropval intostr strcat " lines)" strcat
      count @ 1 + count !
    else
      "+  " logname @ 5 strcut swap pop strcat
      loglib @ logname @ getprop if
        " (" strcat loglib @ logname @ getprop strcat ")" strcat
      then
      tell
    then
    loglib @ logname @ nextprop logname !
  repeat
  count @ 0 = if
    " None" tell
  else
    inarg @ strlen 0 > if
      ">> Displaying/sorting " count @ intostr strcat " logs for \"" strcat
      loglib @ "logs/" inarg @ strcat getprop strcat "\":" strcat tell
    else
      ">> Displaying/sorting " count @ intostr strcat " logs:" strcat tell
    then
    count @ sort
    begin
      count @ 0 > while
      8 strcut swap pop tell
      count @ 1 - count !
    repeat
  then
  ">> Done." tell
;
 
: setlog
    holodeck "recording" getpropstr "yes" strcmp not if
    ">> You must do 'stoplog' first <<" tell
    exit
  then
  log-status "recording" strcmp not if
    ">> That log is already being recorded to! <<" tell
     exit
  then
  inarg @ strlen 0 > if
    loglib @ "logs/" inarg @ strcat getpropval 0 > if
      ">> Current log reset to \"" inarg @ strcat "\"" strcat tell
    else
      ">> New log will be named \"" inarg @ strcat "\"" strcat tell
    then
    holodeck "logname" inarg @ setprop
    holodeck ME @ ">> " ME @ name strcat " sets the log to '" strcat inarg @ strcat "' <<" strcat notify_except
  else
    ">> You must specify a log name. Type 'logs' to list existing logs." tell
  then
;
 
: viewrange
  get-line not if
    ">> There are no recorded lines in this log." tell
    exit
  then
  begin
  startline @ stopline @ <= while
    loglib @ log-propdir startline @ intostr strcat getpropstr inarg !
    inarg @ "||" instring if inarg @ "||" explode pop pop inarg ! then
    inarg @ strlen if
      shownumbers @ if
        "    " 4 startline @ intostr strlen - strcut pop 
        startline @ intostr strcat ": " strcat inarg @ strcat tell
      else
        inarg @
        "<BR>" "<br>" subst
        "I>"   "i>"   subst
        "B>"   "b>"   subst
        "U>"   "u>"   subst
        "<I>"  "<I."  subst
        "</I>" "</I." subst
        CLOSEUP_OPEN "<em><ul>" subst
        CLOSEUP_CLOSE "</ul></em>" subst
        inarg !
        COMMAND @ "printlog" strcmp if
          inarg @
          "/"  "<I>"        subst
          "*"  "<B>"        subst
          "_"  "<U>"        subst
          "/"  "</I>"       subst
          "*"  "</B>"       subst
          "_"  "</U>"       subst
          "[ " CLOSEUP_OPEN   subst
          " ]" CLOSEUP_CLOSE subst
          inarg !
          inarg @ "<hr" instring if
            " ------=====*=====------ " inarg !
          then
          inarg @ "(OOC)" instring not if
            inarg @ "<BR>" instr if
              inarg @ "<BR>" explode count !
              1 index !
              begin
              index @ count @ <= while
                inarg !
                "    " inarg @ striplead strcat tell
                index @ 1 + index !
              repeat
            else
              "    " inarg @ strcat tell
            then
          else
            "  " inarg @ strcat tell
          then
        else
          inarg @ italics-convert bold-convert underline-convert inarg !
          inarg @ "<!--" instring inarg @ " notes:" instring or inarg @ CLOSEUP_OPEN instring or if
            inarg @ tell
          else
            "<P>" inarg @ strcat "</P>" strcat tell
          then
        then
      then
    then
    startline @ 1 + startline !
    doublespace @ if " " tell then
  repeat
;
 
: viewlast
  logname @ strlen 0 = if
    ">> No log selected! Use 'setlog' to select one. <<" tell
    exit
  then
  get-line not if
    ">> There are no recorded lines in this log." tell
    exit
  then
  get-line stopline !
  0 doublespace !
  inarg @ ";" instring 0 > if
    1 shownumbers !
    inarg @ "" ";" subst inarg !
  then
  0 shownumbers !
  inarg @ "#" instring 0 > if
    1 shownumbers !
    inarg @ "" "#" subst inarg !
  then
  inarg @ strlen 0 > if
    stopline @ inarg @ atoi - 1 + startline !
    startline @ 1 < if 1 startline ! then
  else
    stopline @ startline !
  then
  viewrange
;
 
: lastline
  logname @ strlen 0 = if
    ">> No log selected! Use 'setlog' to select one. <<" tell
    exit
  then
  get-line not if
    ">> There are no recorded lines in this log." tell
    exit
  then
  ">> The last line number is "
  get-line intostr strcat tell
;
 
: viewlog
  logname @ strlen 0 = if
    ">> No log selected! Use 'setlog' to select one. <<" tell
    exit
  then
  get-line not if
    ">> There are no recorded lines in this log." tell
    exit
  then
  get-line stopline !
  0 shownumbers !
  0 doublespace !
  inarg @ ";" instring 0 > if
    1 shownumbers !
    inarg @ "" ";" subst inarg !
  then
  1 startline !
  inarg @ "#" instring if
    1 shownumbers !
    inarg @ "" "#" subst inarg !
  then
  inarg @ strlen if
    inarg @ "-" instring if
      inarg @ "-" explode pop atoi startline ! atoi stopline !
    else
      inarg @ atoi startline !
      inarg @ atoi stopline !
    then
  then
  viewrange
;
 
: clearlog
  logname @ strlen 0 = if
    ">> No log selected! Use 'setlog' to select one. <<" tell
    exit
  then
  log-status "recording" strcmp not if
    ">> You must do 'stoplog' first <<" tell
    exit
  then
    logname @ strlen 0 = if
    ">> No log selected! Use 'setlog' to select one. <<" tell
    exit
  then
  auth-user? if
    loglib @ log-prop remove_prop
    holodeck "logname" remove_prop
    ">> Current log \"" logname @ strcat "\" has been removed." strcat tell
  else
    ">> You don't own this log!" tell
  then
;
 
: snapshot
  holodeck ME @ ">>(OOC) " ME @ name strcat " takes a closeup of " strcat targetdb @ name strcat ". (OOC)" strcat notify_except
  ">> Taking closeup of " targetdb @ name strcat tell
  ME @ "_desc_objector" getpropstr switch !
  me @ "_desc_objector" "###" setprop
  targetdb @ "_/de" "Snapshot" 1 parseprop "" "###" subst image !
  image @ 1 strcut pop "@" strcmp not if
  (
    image @ 1 strcut image ! pop
    image @ " " instring spi !
    spi @ if
      image @ spi @ 1 - strcut striplead parg ! pdb !
    else
      image @ pdb !
      "" parg !
    then
    pdb @ 1 strcut pop "$" strcmp not if
      pdb @ match pdb !
    else
      pdb @ atoi dbref pdb !
    then
    "{muf:#" pdb @ intostr strcat 
    parg @ strlen if
      ",{lit:" strcat parg @ strcat "}}" strcat
    else
      ",}" strcat
    then
    image !
    targetdb @ "tmp/snap" image @ setprop
    targetdb @ "tmp/snap" "Snapshot" 0 parseprop image !
    targetdb @ "tmp/snap" remove_prop
  )
    ">> Can't take closeups of program-based descriptions." tell
    me @ "_desc_objector" switch @ setprop
    exit
  then
  me @ "_desc_objector" switch @ setprop
  ME @ location #-1 CLOSEUP_OPEN image @ strcat CLOSEUP_CLOSE strcat notify_except 
;
 
: closeup
  log-status "recording" strcmp if
    ">> Log has not been started yet!" tell
    exit
  then
  inarg @ strlen 0 = if
    "here" inarg !
  then
  inarg @ match targetdb !
  targetdb @ #-1 dbcmp if
    ">> I don't see that here!" tell
  else
    targetdb @ #-2 dbcmp if
      ">> I don't know which one you mean!" tell
    else
      snapshot
    then
  then
;
 
: setline
  logname @ strlen 0 = if
    ">> No log selected! Use 'setlog' to select one. <<" tell
    exit
  then
  inarg @ "=" explode pop startline ! newstring !
  loglib @ log-propdir startline @ strcat getpropstr inarg !
  inarg @ "||" instring if
    inarg @ "||" explode pop inarg ! pop
    inarg @ atoi dbref lineowner !
  else
    ">> You can't overwrite timestamp lines <<" tell
    exit
  then
  ME @ lineowner @ dbcmp auth-user? or if
    loglib @ log-propdir startline @ strcat inarg @ "||" strcat newstring @ strcat setprop
    ">> Line set." tell
  else
    ">> You aren't authorized to change that line." tell
  then
;
 
: swaplines
  logname @ strlen 0 = if
    ">> No log selected! Use 'setlog' to select one. <<" tell
    exit
  then
  get-line not if
    ">> There are no recorded lines in this log." tell
    exit
  then
  inarg @ "=" explode pop atoi startline ! atoi stopline !
  
  auth-user? if
    loglib @ log-propdir startline @ intostr strcat getpropstr oldstring !
    loglib @ log-propdir stopline @ intostr strcat getpropstr newstring !
    loglib @ log-propdir startline @ intostr strcat newstring @ setprop
    loglib @ log-propdir stopline @ intostr strcat oldstring @ setprop
    ">> Lines swapped." tell
  else
    ">> You aren't authorized to swap those lines." tell
  then
;
 
: changeline
  logname @ strlen 0 = if
    ">> No log selected! Use 'setlog' to select one. <<" tell
    exit
  then
  get-line not if
    ">> There are no recorded lines in this log." tell
    exit
  then
  inarg @ "=" explode pop atoi startline ! oldstring ! newstring !
  loglib @ log-propdir startline @ intostr strcat getpropstr inarg !
  inarg @ "||" instring if
    inarg @ "||" explode pop atoi dbref lineowner ! pop
  else
    ">> You can't change timestamp lines <<" tell
    exit
  then
  auth-user? ME @ lineowner @ dbcmp or if
    inarg @ newstring @ oldstring @ subst inarg !
    loglib @ log-propdir startline @ intostr strcat inarg @ setprop
    ">> Line " startline @ intostr strcat " updated to: " strcat inarg @ "||" explode pop pop strcat tell
  else
    ">> You aren't authorized to make a change to that line." tell
  then
;
 
: deleteline
  logname @ strlen 0 = if
    ">> No log selected! Use 'setlog' to select one. <<" tell
    exit
  then
  get-line not if
    ">> There are no recorded lines in this log." tell
    exit
  then
  inarg @ atoi startline !
  loglib @ log-propdir startline @ intostr strcat getpropstr inarg !
  inarg @ "||" instring if
    inarg @ "||" explode pop atoi dbref lineowner ! pop
  else
    ">> You can't delete timestamp lines <<" tell
    exit
  then
  auth-user? ME @ lineowner @ dbcmp or if
    loglib @ log-propdir startline @ intostr strcat remove_prop
    ">> Line deleted." tell
  else
    ">> You aren't authorized to delete that line." tell
  then
;
 
: help
  "How to use Cambot:" tell
  "  cambot           : Display commands and status" tell
  "  startlog         : Starts cambot logging (Sets timestamp)" tell
  "  stoplog          : Stops logging." tell
  "  viewlog          : Views the entire log." tell
  "  viewlog m        : Views line m of the log." tell
  "  viewlog m-n      : Views lines m through n of the log." tell
  "  viewlast         : Views the last recorded line." tell
  "  viewlast n       : Views the last n lines of the log." tell
  "  printlog         : Views the entire log as HTML." tell
  "  Using # in the arg to viewlog or viewlast lists line numbers." tell
  "  closeup x        : Records the description of object/player x." tell
  "  closeup          : Records the description of current room." tell
  "  addnote x        : Records HTML comment 'x' into the log." tell
  "  icdate x x x     : Embeds IC date, ex: 10 Unity 6107." tell
  "  hr               : Adds a horizontal-rule to the log." tell
  "  logs             : Lists current and stored log names." tell
  "  setlog n         : Sets the current log to n." tell
  "  clearlog         : Deletes the current log." tell
  "Editing Commands:" tell
  "  setline n=x      : Sets line n of the log to string x." tell
  "  deleteline n     : Deletes line n of the log." tell
  "  changeline n=x=y : Changes string x to string y in line n." tell
  "  swapline x=y     : Swap line x with line y." tell
  "  lastline         : Shows you the current line number." tell
  "Current Status:" tell
  "  Recording: " holodeck "recording" getpropstr strcat tell
  "  Current log: "
  holodeck "logname" getpropstr logname ! logname @ strlen 0 > if
    logname @ strcat tell
    "  Log Length: " loglib @ "logs/" logname @ strcat getpropval intostr strcat tell
  else
    "none" strcat tell
  then
;
 
: main
  prog "recorder" getpropstr recorder !
  depth 0 > if inarg ! then
  holodeck "library" envprop swap #-1 dbcmp not if loglib ! then
  loglib @ string? if
    loglib @ strlen 0 > if
      loglib @ atoi dbref loglib !
    else
      holodeck loglib !
    then
  else
    holodeck loglib !
  then
  TRIGGER @ name ACTION_NAME strcmp if
    TRIGGER @ ACTION_NAME setname
  then
  get-logname
  COMMAND @ case
    "cambot" over strcmp not when help end
    "closeup" over strcmp not when closeup end
    "logs" over strcmp not when logs end
    "setlog" over strcmp not when setlog end
    "clearlog" over strcmp not when clearlog end
    "setline" over strcmp not when setline end
    "deleteline" over strcmp not when deleteline end
    "changeline" over strcmp not when changeline end
    "swapline" over strcmp not when swaplines end
    "lastline" over strcmp not when lastline end
    "startlog" over strcmp not when startlog end
    "stoplog" over strcmp not when stoplog end
    "viewlog" over strcmp not when viewlog end
    "printlog" over strcmp not when viewlog end
    "viewlast" over strcmp not when viewlast end
    "addnote" over strcmp not when addnote end
    "hr" over strcmp not when addbreak end
    "icdate" over strcmp not when icdate end
  endcase
;
.
c
q
@set cambot_action.muf=L
@set cambot_action.muf=sortlist: