@edit library_action.muf
1 9999 d
1 i
( library_action.muf 11/04/01 by BoingDragon
  This is part of the Cambot holodeck system, for use with cambot and vista
  actions. It allows the user to set the local holodeck to use a specific
  object that they own as the source/destination for all vista and log data.
 
  Simply link a 'library' action to this program from the holodeck or from
  a cambot environment room.
)
lvar loglib
lvar count
lvar index
lvar authlist
 
: auth-user?
  loglib @ owner ME @ dbcmp ME @ "W" flag? or if
    1
  else
    0 index !
    loglib @ "_auth_users" getpropstr authlist !
    authlist @ strlen if
      authlist @ " " explode count !
      begin
      count @ 0 > while
        atoi dbref ME @ dbcmp if 1 index ! then
        count @ 1 - count !
      repeat
    then
    index @ 
  then
;
  
: main
  dup strlen if
    loglib !
  else
    ">> Usage: " COMMAND @ strcat " <name of library object>" strcat .tell
    ">> To reset to the default library, use '" COMMAND @ strcat " default'" strcat .tell
    exit
  then
  ME @ location "recording" getpropstr "yes" strcmp not if
    ">> You can't change libraries while a log is in progress!" .tell
    exit
  then
  loglib @ "default" strcmp not if
    ME @ location "library" remove_prop
    ME @ location "logname" remove_prop
    ">> Resetting to default library." .tell
    exit
  then
  loglib @ match loglib !
  loglib @ #-1 dbcmp if
    ">> I don't see that here." .tell
    exit
  then
  loglib @ #-3 dbcmp if
    ">> I don't know which one you mean." .tell
    exit
  then
  auth-user? not if
    ">> You aren't authorized to use that library!" .tell
    exit
  else
    loglib @ thing? not if
      ">> That isn't an object." .tell
      exit
    else
      ME @ location "library" loglib @ intostr setprop
      ME @ location "logname" remove_prop
      ">> Library for logs and vistas set to '" loglib @ name strcat "'" strcat .tell
    then
  then
;
.
c
q
@set library_action.muf=L